home *** CD-ROM | disk | FTP | other *** search
/ Compendium Deluxe 1 / LSD Compendium Deluxe 1.iso / a / programming / assembly / new_line.lha / new_line!.s < prev    next >
Encoding:
Text File  |  1992-09-02  |  3.8 KB  |  196 lines
  1. ; *******************************************
  2. ; * This is one of the fastes Line-Routine. *
  3. ; * At the moment without clipping.        *
  4. ; *******************************************
  5. ;
  6. ;
  7. ; This Sources is done by MCM/Complex and improved by Tron/Sanity
  8. ;
  9. ; 
  10.  
  11.  
  12.  
  13.  
  14.  
  15.  
  16.     org    $20000
  17.     load    $20000
  18.  
  19. WaitBlit    MACRO
  20. .\@1    BTST    #14,2(A5)
  21.     BNE.S    .\@1
  22.         ENDM
  23.  
  24. Plane    =    $50000
  25.  
  26. J:
  27.     move.l    #More,$80.W
  28.     trap    #0
  29.     rts
  30.  
  31. MORE:
  32.     move.w    #$2700,sr
  33.     lea    $DFF000,A5
  34.     bsr    clear
  35.     bsr    InitBlitSizes
  36.     bsr    InitYPosTab
  37.     move.l    #ucp,$84(a5)
  38.     bsr    InitLine
  39.  
  40.     lea    Plane,A0
  41.     move    #0,d0
  42.     move    #0,d1
  43.     move    #100,d2
  44.     move    #100,d3
  45.     bsr    BlitLine
  46.     
  47. Wait:
  48.     btst    #2,$16(a5)
  49.     bne.s    Wait
  50.  
  51.     move.w    #$2000,sr
  52.     rte
  53.  
  54. Clear:
  55.     lea    Plane,a0
  56.     move.w    #101*40/4-1,d1
  57.     moveq    #0,d0
  58. Clear0:
  59.     move.l    d0,(a0)+
  60.     dbf    d1,Clear0
  61.  
  62.     move.w    #156*40/4-1,d1
  63. *    move.l    #$AAAAAAAA,d0
  64. Clear1:
  65.     move.l    d0,(a0)+
  66.     dbf    d1,Clear1
  67.     rts
  68.     
  69. UCP:
  70.     dc.w    $96,$87C0,$108,0,$8e,$2981,$90,$29c1,$92,$38,$94,$d0
  71.     dc.w    $e0,Plane/$10000,$e2,Plane&$FFFF,$100,$1200,$102,0
  72.     dc.l    $fffffffe
  73.     
  74. InitBlitSizes:
  75.     LEA    LINE_BlitSizes(PC),A0
  76.     MOVEQ    #0,D0
  77.     MOVE.W    #$3FF,D2
  78. .loop
  79.     MOVE    D0,D1
  80.     LSL.W    #6,D1
  81.     ADDQ.W    #2,D1
  82.     MOVE    D1,(A0)+
  83.     ADDQ.W    #1,D0
  84.     DBF    D2,.loop
  85.     RTS
  86.     
  87. InitYPosTab:
  88.     LEA    YPosTab(PC),A0
  89.     MOVEQ    #0,D0
  90.     MOVE.W    #255,D1
  91. .loop
  92.     MOVE    D0,(A0)+
  93.     ADD.W    #40,D0
  94.     DBF    D1,.loop
  95.     RTS
  96.  
  97. InitLine:
  98.     WaitBlit
  99.     MOVEQ    #-1,D0
  100.     MOVE.L    D0,$44(A5)        ;BLTAFWM = $FFFF (BLTALWM egal!)
  101.     MOVE.L    #$FFFF8000,$72(A5)    ;BLTBDAT = Maske, BLTADAT = $8000
  102.     MOVE.W    #$0028,$60(A5)        ;BLTCMOD = Breite der Plane
  103.     MOVE.W    #0,$42(A5)        ;BLTCON1 löschen
  104.     LEA    YPosTab(PC),A1
  105.     LEA    LINE_BlitSizes(PC),A2
  106.     RTS
  107.  
  108. *-------------------------------- BlitLine -----------------------------*
  109. *
  110. *    IN:    D0/D1        x1,y1
  111. *        D2/D3        x2,y3
  112. *        A0        Plane
  113. *        A1    (*)    YPosTab
  114. *        A2    (*)    LINE_BlitSizes
  115. *        A5    (*)    Custom-Base $DFF000
  116. *
  117. *        D4        work register
  118. *
  119. *        (*)        will remain untouched
  120. BlitLine:
  121.     CMP.W    D1,D3        ;Blitter im Single-Modus
  122.     BEQ.S    .end        ;--> Keine horizontalen Linien!!!
  123.     BGT.S    .y2_gt_y1    ;Y2 > Y1 ??? Ja --> branch
  124.     EXG    D0,D2        ;Nein --> Oktanten "klappen"
  125.     EXG    D1,D3        ;--> Nur Oktanten 4,5,6,7 möglich!!!
  126. .y2_gt_y1
  127.     MOVE    D1,D4
  128.     ADD    D4,D4
  129.     ADD.W    (A1,D4.W),A0
  130.     MOVE    D0,D4
  131.     ASR.W    #3,D4
  132.     LEA    (A0,D4.W),A0
  133.  
  134.     MOVEQ    #1,D4        ;Oktant 6/7
  135.     SUB    D0,D2        ;X2 > X1 (DeltaX)
  136.     BPL.S    .x2_gt_x1    ;DeltaX positiv --> Oktant 6/7
  137.     NEG    D2        ;DeltaX negativ --> Positiv machen
  138.     MOVEQ    #0,D4        ;jetzt nur noch Oktanten 4/5 möglich!!! 
  139. .x2_gt_x1
  140.     SUB    D1,D3        ;DeltaY
  141.  
  142.  
  143.     MOVE    D3,D1
  144.     ADD    D1,D1
  145.     CMP.W    D2,D1
  146.     DBHI    D3,.1
  147. .1
  148.     MOVE    D3,D1        
  149.     SUB    D2,D1        ;DeltaY > Delta X ??? (SUB.W wegen X-Flag!!!!)
  150.     BGT.S    .dy_gt_dx    ;Ja --> D3 schon GDelta und D2 KDelta
  151.     EXG    D2,D3        ;Nein -> D3 zu GroßDelta, D2 zu KDelta machen
  152. .dy_gt_dx
  153.     ADDX    D4,D4        ;D4 mit D4 und X-Flag addieren
  154.         ;bei Oktant 4/5 (D4=0) und dy>dx -> X-Flag=0 -> D4=0 OKT 5
  155.         ;bei Oktant 4/5 (D4=0) und dy<dx -> X-Flag=1 -> D4=1 OKT 4
  156.         ;bei Oktant 6/7 (D4=1) und dy>dx -> X-Flag=0 -> D4=2 OKT 6
  157.         ;bei Oktant 6/7 (D4=1) und dy<dx -> X-Flag=1 -> D4=3 OKT 7
  158.  
  159.     ADD    D2,D2        ;2*KDelta
  160.     MOVE    D2,D1        
  161.     SUB    D3,D2        ;2*KDelta - GDelta
  162.     ADDX    D4,D4        ;wenn 2*KDelta - GDelta <0 --> SIGN-Bit setzen!
  163.  
  164.     ADD    D0,D0
  165.     ANDI.W    #$001F,D0
  166.  
  167.     WaitBlit
  168.     MOVE    BltCon0(PC,D0.W),$40(A5)    ;BltCON0 = $xB4A
  169.     MOVE.B    BltCon1(PC,D4.W),$43(A5)    ;BltCON1 = $00xx
  170.     
  171.     MOVE    D2,$52(A5)    ;BLTAPTL = 2*KDelta - GDelta    
  172.     SUB    D3,D2        ;D2 = 2*KDelta - 2*GDelta
  173.     ADD    D3,D3
  174.     MOVEM.W    D1/D2,$62(A5)    ;BLTBMOD=2*KDelta, BLTAMOD=2*KDelta-2*GDelta
  175.     MOVE.L    A0,$48(A5)
  176.     MOVE.L    A0,$54(A5)
  177.     MOVE    (A2,D3.W),$58(A5)    
  178. .end
  179.     rts
  180.  
  181. BltCon0:
  182.     DC.W    $0B4A,$1B4A,$2B4A,$3B4A,$4B4A,$5B4A,$6B4A,$7B4A
  183.     DC.W    $8B4A,$9B4A,$AB4A,$BB4A,$CB4A,$DB4A,$EB4A,$FB4A
  184. BltCon1:
  185.     DC.B    $0B    ;Sign 0, Oktant 5, Single, Line
  186.     DC.B    $4B    ;Sign 1, Oktant 5, Single, Line
  187.     DC.B    $17    ;Sign 0, Oktant 4, Single, Line
  188.     DC.B    $57    ;Sign 1, Oktant 4, Single, Line
  189.     DC.B    $03    ;Sign 0, Oktant 6, Single, Line
  190.     DC.B    $43    ;Sign 1, Oktant 6, Single, Line
  191.     DC.B    $13    ;Sign 0, Oktant 7, Single, Line
  192.     DC.B    $53    ;Sign 1, Oktant 7, Single, Line
  193.  
  194. LINE_BlitSizes:        BLK.W    1024,0
  195. YPosTab:        BLK.W    256,0
  196.